# Uebungsblatt 11 - Gnuplot
# Name: Joe User
#

##############################
# 11.1 Messdaten darstellen
##############################
# 11.1.1 Befehl zum Plotten der Daten
plot [-5:10] "histo.dat" using 3:1 with linespoints

# 11.1.2 Befehl zum Plotten der Daten mit Fehlerbalken
plot "histo.dat" using 3:1:2 with yerrorbars


##############################
# 11.2 Fitfunktionen
##############################
# 11.2.1 Fitbefehle
p(x) = l**x / gamma(x+1.0) * exp(-l)
f(x) = a4*x**4 + a3*x**3 + a2*x**2 + a1*x + a0
g(x) = A*exp(-B*(x-m)**2)
g2(x) = A2*exp(-B2*(x-m2)**2)

# Startwerte setzen für viertens:
A2=-1;B2=-1;m2=-1

# Fit der 4 Funktionen:
fit p(x) "histo.dat" using 3:1 via l
fit f(x) "histo.dat" using 3:1 via a4,a3,a2,a1,a0
fit g(x) "histo.dat" using 3:1 via A,B,m
fit g2(x) "histo.dat" using 3:1 via A2,B2,m2

plot "histo.dat" using 3:1:2 with yerrorbars, p(x), f(x), g(x)

# Was ist bei Punkt 4 passiert?
# Die Startwerte sind unrealistisch (sigma**2 = -1), deshalb
# konvergiert der Fit ins falsche Lösungsminimum.
# Daraus lernt man: gnuplot Fits sind bei weitem nicht perfekt!
# Man sollte immer optisch oder per Chi**2 kontrollieren, ob
# vielleicht das falsche Minimum gefunden wurde.

# 11.2.2 Qualitaet der Fits
# Welche Funktion eignet sich rein optisch am besten?
# Die Gauss-Funktion (Punkt 3)

# Welches sind die Chi-quadrat-Werte?
# 1. Poisson: 0.00337131
# 2. Polynom: 0.000180268
# 3. Gauss: 5.90468e-05
# 4. Gauss, Startwerte: 2.56063e+86
# Was sind die Parameter des besten Fits?
# Für Gauss-Funktion:
# A               = 0.156663         +/- 0.002849     (1.819%)
# B               = 0.0779998        +/- 0.00328      (4.205%)
# m               = 1.00518          +/- 0.05316      (5.289%)


# 11.2.3 Befehle zum schoenen Plotten

# Beschriftung
set title "Normalverteilung"
set xlabel "Wert"
set ylabel "Wahrscheinlichkeit"
# Legende:
plot "histo.dat" u 3:1 t "Daten", g(x) t "Fit"
# Schriftgroesse skalieren:
set terminal x11 font "Helvetica,18"
# Linie dicker machen:
plot "histo.dat" u 3:1 t "Daten", g(x) t "Fit" lw 3
# Balkendiagramm:
plot "histo.dat" u 3:1:(0.3) w boxes t "Daten" fs solid 0.7, g(x) lw 2 lc 3 t "Fit"
# oder mit ausführlichen Optionsnamen:
plot "histo.dat" using 3:1:(0.3) with boxes title "Daten" fillstyle solid 0.7, g(x) linewidth 2 linecolor 3 title "Fit"


##############################
# 11.3 Plot speichern
##############################
# Befehl zum Speichern des Plots
set terminal postscript eps enhanced color solid font "Helvetica,15"
set output "plot.eps"
replot